BARRIERA INFINITA IN UNA DIMENSIONE

AUTOSTATI DELL’ ENERGIA



L’energia potenziale della particella e’ U(x) = {0 per x<a ; ∞ per x>a}: questo equivale a porre U(x) = 0 nell’operatore Hamiltoniano H e a richiedere

 φ(x) = 0 per x > a   ;     φ(x ->a+) = 0                                (1)

L’eq. degli autostati dell’energia (fisso qui m=1/2 e (Subscript[h, reduced])=1) e’ dunque

H φ(E,x) == - (∂_(x,x))φ(E,x) = E φ(E,x)                      (2)

con E ≥ 0. La (2) ha 2 soluzioni indipendenti, (e^(i(Sqrt[E]) x)) ed (e^(-i(Sqrt[E]) x)) : imponendo le condizioni  (1) si trova

φ(E,x)=(1/(2(Sqrt[π])(E^(1/4))))((e^(i(Sqrt[E]) x))-(e^(i2(Sqrt[E]) a))(e^(-i(Sqrt[E]) x)))HeavisideTheta[a-x]            (3)

dove le φ(E,x) sono normalizzate in modo da formare un sistema ortonormale:

(∫_(-∞)^∞)(SuperStar[φ])(E',x) φ(E,x) dx = DiracDelta (E-E’)                         (4)

Vale anche:

(∫_0^∞)(SuperStar[φ])(E,x) φ(E,y) dE   =  DiracDelta (x-y)*HeavisideTheta[a-x]                                                   (4)’

Il sistema ortonormale (3) e’ anche completo nel sottospazio definito da (1) e dalla condizione che φ(x) si possa esprimere mediante trasformata di Fourier (la trasformata mediante il sistema (3) equivale ad una trasformata di Fuorier seno).

SCATTERING

Fissata una generica Ψ(0,x) iniziale (che soddisfi le (1) ), la funzione d’onda Ψ(t,x) all’istante t della particella  nel potenziale U(x) precedente e’ soluzione dell’eq. di Schrodinger 

i (∂_t) Ψ(t,x) = H  Ψ(t,x)==- (∂_(x,x))Ψ(t,x)     <==>     Ψ(t,x) =   (e^(- i H t ))Ψ(0,x)       (5)

con le condizioni al contorno (1). La Ψ(0,x) iniziale puo’ esser sviluppata nel sistema completo (3):

Ψ(0,x) = (∫_0^∞)c(E) φ(E,x)dE                                             (6)

dove il coefficiente dello sviluppo c(E) rappresenta fisicamente l’ampiezza di densita’ di probabilita’ dell’energia nello stato Ψ(0,x). Da (4) segue:

c(E) = (∫_(-∞)^∞)(SuperStar[φ])(E,x) Ψ(0,x) dx                             (7)

e sostituendo (6) e (7) nella (5) segue

Ψ(t,x) = (∫_0^∞)c(E)  (e^(- i E t ))φ(E,x)dE  =

           = (∫_(-∞)^∞)dy G(t,x,y) Ψ(0,y)                    (8) 
dove 

G(t,x,y) = (∫_0^∞)dE  (SuperStar[φ])(E,y) (e^(- i E t ))φ(E,x)   =

              =  ((((1/2)-(i/2)))/((Sqrt[2 π]) (Sqrt[t]))) ((e^((i (((x-y))^2))/(4 t)))-(e^((i (((-2 a+x+y))^2))/(4 t)))) HeavisideTheta[a-x,a-y]                    (9)

e’ detta “funzione di trasformazione” o “funzione di Green” o “propagatore” dell’eq. di Schrodinger (5) con le condizioni al contorno (1).  
Assegnata una generica Ψ(0,x) iniziale, la (8) risolve il problema.

(Nota: la funzione Integrate non e’ in grado di calcolare integrali che hanno come risultato funzioni delta di Dirac; bisogna usare FourierTransform)

FUNZIONE D’ONDA INIZIALE Ψ(0,x)

Possiamo fissare una qualsiasi Ψ(0,x) iniziale che soddisfi le condizioni (1): ad esempio 

Ψ(0,x) = HeavisideTheta[x-(Subscript[x, 1])]*HeavisideTheta[-x+(Subscript[x, 2])]*(e^(i*(Subscript[p, 0])*x))      

rappresenta una particella inizialmente confinata in (Subscript[x, 1]) < x < (Subscript[x, 2]) con ampiezza di densita’ di probabilita’ dell’impulso c(p) data da 

c(p) = FourierTransform[Ψ(0,x) , x , -p] = -(((e^((9/2) i (-5+p))) (Sqrt[(2/π)]) Sin[(15/2)-((3 p)/2)])/(-5+p))            

che, in accordo col principio di indeterminazione, si restringe intorno a p = (Subscript[p, 0]) al crescere di |(Subscript[x, 2])-(Subscript[x, 1])|.

__________________________________________________________________

equazioni (3) e (4):

Remove[φ,e,a,c]
φ[e_,x_]=c*((E^(I*(Sqrt[e]) x))-(E^(I*2*(Sqrt[e]) a))*(E^(-I*(Sqrt[e]) x)))*HeavisideTheta[a-x]
(SuperStar[φ])[e_,x_]=(SuperStar[c])*((E^(-I*(Sqrt[e]) x))-(E^(-I*2*(Sqrt[e]) a))*(E^(+I*(Sqrt[e]) x)))*HeavisideTheta[a-x]

Collect[
(SuperStar[φ])[e1,x]*φ[e,x]/.((HeavisideTheta[x_])^2)->HeavisideTheta[x],
(E^(I x_))]

Clear[scal,scal1,scal2]
scal1=(Sqrt[2 π])*FourierTransform[c ((E^(-I (Sqrt[e1]) x))-(E^(-2 I a (Sqrt[e1])+I (Sqrt[e1]) x))) HeavisideTheta[a-x] (SuperStar[c]),x,(Sqrt[e])]//FullSimplify;
scal2=(Sqrt[2 π])*FourierTransform[c (E^(2 I a (Sqrt[e]))) ((E^(-I (Sqrt[e1]) x))-(E^(-2 I a (Sqrt[e1])+I (Sqrt[e1]) x))) HeavisideTheta[a-x] (SuperStar[c]),x,-(Sqrt[e])]//FullSimplify;
scal=Expand[(scal1-scal2)/.DiracDelta[(Sqrt[e])+(Sqrt[e1])]->0]/.DiracDelta[-(Sqrt[e])+(Sqrt[e1])]->DiracDelta[(Sqrt[e])-(Sqrt[e1])]
scal=%/.{(E^(I a ((Sqrt[e])-(Sqrt[e1]))))->1,DiracDelta[(Sqrt[e])-(Sqrt[e1])]->2 (Sqrt[e])DiracDelta[e-e1],c->(1/(2*(Sqrt[π])*(e^(1/4)))),(SuperStar[c])->(1/(2*(Sqrt[π])*(e^(1/4))))}

Remove[φ,e,a,c] (* autofunzioni (3)   *)
φ[e_,x_]=(1/(2*(Sqrt[π])*(e^(1/4))))*((E^(I*(Sqrt[e]) x))-(E^(I*2*(Sqrt[e]) a))*(E^(-I*(Sqrt[e]) x)))*HeavisideTheta[a-x];
(SuperStar[φ])[e_,x_]=(1/(2*(Sqrt[π])*(e^(1/4))))*((E^(-I*(Sqrt[e]) x))-(E^(-I*2*(Sqrt[e]) a))*(E^(+I*(Sqrt[e]) x)))*HeavisideTheta[a-x];

equazione (4)':

(* (∫_0^∞)(SuperStar[φ])(E,x) φ(E,y) \[DifferentialD]E  =(∫_0^∞)(SuperStar[φ])((p^2),x) φ((p^2),y) 2p\[DifferentialD]p = *)

Simplify[2*p*(SuperStar[φ])[(p^2),x]*φ[(p^2),y],Assumptions->p>0]*HeavisideTheta[p]

Simplify[(Sqrt[2 π])*FourierTransform[(((E^(-I p (2 a+y))) (-(E^(2 I a p))+(E^(2 I p x))) ((E^(2 I a p))-(E^(2 I p y))) HeavisideTheta[p] )/(2 π)),
p,-x]/.{DiracDelta[2 a-x-y]->0,DiracDelta[-2 a+x+y]->0,DiracDelta[-x+y]->DiracDelta[x-y]}]

Propagatore, eq. (9):

Clear[fun,a]
fun[t_,x_,y_]=(Sqrt[2 π])*FourierTransform[(SuperStar[φ])[e,y]*φ[e,x]*HeavisideTheta[e],e,-t,Assumptions->a∈Reals]//Simplify

Clear[fun,a]
fun[t_,x_,y_]=(1/(4 (Sqrt[2 π]) ((Abs[t])^(3/2))))HeavisideTheta[a-x] HeavisideTheta[a-y] (t (-2 (Cos[((((x-y))^2)/(4 t))]-Cos[((((x-y))^2)/(4 Abs[t]))]) FresnelC[((x-y)/((Sqrt[2 π]) (Sqrt[Abs[t]])))]-I (Cos[((((x-y))^2)/(4 t))]+Cos[((((x-y))^2)/(4 Abs[t]))]-2 (Cos[((((-2 a+x+y))^2)/(4 Abs[t]))]+Sin[((((x-y))^2)/(4 Abs[t]))]-Sin[((((-2 a+x+y))^2)/(4 Abs[t]))])))+Abs[t] (Cos[((((x-y))^2)/(4 t))]+Cos[((((x-y))^2)/(4 Abs[t]))]-2 Cos[((((-2 a+x+y))^2)/(4 Abs[t]))]+2 I (Cos[((((x-y))^2)/(4 t))]-Cos[((((x-y))^2)/(4 Abs[t]))]) FresnelS[((x-y)/((Sqrt[2 π]) (Sqrt[Abs[t]])))]+2 Sin[((((x-y))^2)/(4 Abs[t]))]-2 Sin[((((-2 a+x+y))^2)/(4 Abs[t]))]))/.Abs[t_]->t//FullSimplify

Clear[fun,a]
fun[t_,x_,y_]=((((1/2)-(I/2)) ((E^((I (((x-y))^2))/(4 t)))-(E^((I (((-2 a+x+y))^2))/(4 t)))) HeavisideTheta[a-x,a-y])/((Sqrt[2 π]) (Sqrt[t]))); (* propagatore  *)

Funzione d'onda iniziale :

Clear[Ψ0,c,p0]
a=0;
p0=5;
Ψ0[x_]=HeavisideTheta[x-(-6)]*HeavisideTheta[-x+(-3)]*(E^(I*p0*x)) (* funziona d'onda iniziale *)
c[p_]=FourierTransform[Ψ0[x],x,-p] (* ampiezza di densita' di probabilita' degli impulsi iniziale  *)

(*
Clear[Ψ0,c,p0];
a=0;
p0=5;
Ψ0[x_]=Which[x≤-6,0,-6<x≤-5,x+6,-5<x≤-4,1,-4<x≤-3,-x-3,-3<x,0] *(E^(I*p0*x));
c[p_]=FourierTransform[Ψ0[x],x,p]
*)

Plot[((Abs[Ψ0[x]])^2),{x,-10,10},PlotRange->All]
Plot[((Abs[c[p]])^2),{p,-10,10},PlotRange->All]

Soluzione, eq. (8):

fun[t,x,y]*Ψ0[y] (*  integranda della (8)  *)

Clear[Ψ]
Ψ[t_,x_]=Integrate[fun[t,x,y]*Ψ0[y],{y,-∞,∞}]
(* oppure 
Ψ[t_,x_]=(Sqrt[2*π])*FourierTransform[(1/((Sqrt[2 π]) (Sqrt[t])))((1/2)-(I/2))  ((E^((I (((x-y))^2))/(4 t)))-(E^((I (((x+y))^2))/(4 t)))) HeavisideTheta[-3-y] HeavisideTheta[6+y] HeavisideTheta[-x,-y],y,p0,Assumptions->{t>0,x∈Reals,y∈Reals}]
*)

Verifica

Simplify[I*(∂_t) Ψ[t,x]+(∂_(x,x))Ψ[t,x],Assumptions->{x>0 || x<0}]

Plot[Abs[Ψ[(10^(-8)),x]],{x,-10,0},PlotRange->All,Filling->Bottom]

Animazione

Animate[Plot[((Abs[Ψ[t,x]])^2),{x,-20,0},PlotRange->{{-20,0},{0,6}},Filling->Bottom],{t,(10^(-8)),2},AnimationRunning->False]